// Retrival zur Überprüfung der RE-Annahmen
// ----------------------------------------

clear
set memory 120m
set scheme s1mono
set more off
	
// Retrival
// --------

mkdat                                                               ///
  afamstd bfamstd cfamstd dfamstd efamstd ffamstd gfamstd hfamstd   ///
  ifamstd jfamstd kfamstd lfamstd mfamstd nfamstd ofamstd pfamstd   ///
  qfamstd rfamstd sfamstd tfamstd ufamstd vfamstd                   ///
  egp84 egp85 egp86 egp87 egp88 egp89 egp90 egp91 egp92 egp93 egp94 ///
  egp95 egp96 egp97 egp98 egp99 egp00 egp01 egp02 egp03 egp04 egp05 ///
  using data/                                                       ///
  , files(pgen) waves(a b c d e f g h i j k l m n o p q r s t u v)  ///
    netto(1) keep(sex gebjahr) clear

holrein ///
 ap08 bp16 cp16 dp12 ep12 fp10 gp12 hp15 ip15 jp15 kp25 lp21 mp15 np11 ///
 op09 pp10 qp10 rp12 sp15 tp34 up09 vp10                               ///
 using data/                                                           ///
 , files(p) waves(a b c d e f g h i j k l m n o p q r s t u v )

holrein                                                         ///
 e1110184 e1110185 e1110186 e1110187 e1110188 e1110189 e1110190 ///
 e1110191 e1110192 e1110193 e1110194 e1110195 e1110196 e1110197 ///
 e1110198 e1110199 e1110100 e1110101 e1110102 e1110103 e1110104 ///
 e1110105                                                       ///
 using data/                                                    ///
 ,  files(pequiv) waves(a b c d e f g h i j k l m n o p q r s t u v )

// Prepare employment status
// -------------------------

local i 1984
foreach var of varlist ap08 bp16 cp16 dp12 ep12 fp10 gp12 hp15 ip15 ///
  jp15 kp25 lp21 mp15 np11 op09 pp10 qp10 rp12 { 
    gen unemp`i++' = `var' >= 7 & !mi(`var')
    drop `var'
}

foreach var of varlist  sp15 tp34 up09 vp10 { 
    gen unemp`i++' = `var' >= 7 & !mi(`var')
    drop `var'
}


// Reshape
// -------

soepren egp*, new(egp) wave(1984/2005)
soepren ?famstd,  new(fam) w(1984/2005)
soepren ?hhnr, new(hnr) w(1984/2005)
soepren ?netto, new(netto) w(1984/2005)
soepren e11101??, new(whours) w(1984/2005)

reshape long ///
   hnr unemp egp income whours fam netto, i(persnr) j(welle)


// Recode Variables
// ----------------

// Work hours
replace whours = . if whours < 0
replace whours = whours/52

// Age
gen age = welle - gebjahr

// Gender
gen men = sex==1 if !mi(sex)


// Listwise Deletion
// -----------------

mark touse
markout touse whours men age unemp 

// Center age
sum age
gen zage = age - r(mean) 


// Regression Modell
// -----------------

xtmixed whours zage men unemp || persnr: zage, cov(unstr)

// Graph empirical bayes predictions of constants and slopes
predict reff*, reffects
gen cons  = reff2 + _b[_cons]
gen slope = reff1 + _b[zage]
scatter cons slope

// Regression lines
gen Yhat = cons + slope*zage + _b[men]
line Yhat age if inrange(age,20,40), c(L)

exit