* Graphiken Model 3 (zeitverzögert, permanent)
version 7.0

* -----------------------------------------------------------------

* ADO-INSTALLATION 
* ----------------

* The following section automatically installs Ado-Files over the
* Internet. You need to have a conection to the internet for this.
* If you don't have a connection to the internet you need to commend 
* out the entire section. In this case you have to install the ados
* by hand (See [U] 32 or Kohler/Kreuter (2001))

capture which mmerge
if _rc ~= 0 {
	ssc install mmerge 
}

* ---------------------------------------------end of installing section. 


* Is be.dta already there? If not, create
capture describe using be
if _rc ~= 0 {
	do crbe
}


* Get Data from Fixed-Effects Model
capture use mod3, clear
if _rc ~= 0 {
	do anmod3
	use mod3, clear
}
sort uv

mmerge uv using be
drop _merge


* Reshape to wide
* ---------------

gen ifinder = substr(uv,-1,1) == "i"
replace uv = reverse(substr(reverse(uv),2,.)) if ifinder==1
drop index
drop if uv== "."
reshape wide bleft1 bkons1 bkons_be bleft_be, i(uv) j(ifinder)

* Sum up interaktions
* -------------------

ren bleft10 bleft0
ren bkons10 bkons0
gen bleft1 = bleft0 + 3 * bleft11
gen bkons1 = bkons0 + 3 * bkons11
drop bleft11 bkons11
ren bleft_be0 bleft_be
ren bkons_be0 bkons_be

*  Generating Timepaths                                   
*  --------------------

gen finder = .
gen t = _n in 1/10
lab var t " "
lab val t t
lab def t 5 "event"

foreach piece in arbsel selarb parspd parcdu {
  replace finder = uv=="e`piece'"
  sort finder
  * Left-Model, No political interest
  gen `piece'fl0 = 0
 replace `piece'fl0 = `piece'fl0 + bleft0[_N] * (1 + ln(t-4)) if t>=5 & t ~= .
  * Left-Model, Political interest
  gen `piece'fl1 = 0
  replace `piece'fl1 = `piece'fl1 + bleft1[_N] * (1 + ln(t-4)) if t>=5 & t ~= .
  * Between effects
  gen `piece'bl = bleft_be[_N] if t ~= .
  * Kons-Model, No political interest
  gen `piece'fc0 = 0
  replace `piece'fc0 = `piece'fc0 + bkons0[_N] * (1 + ln(t-4)) if t>=5 & t ~= .
  * Kons-Model, Political interest
  gen `piece'fc1 = 0
  replace `piece'fc1 = `piece'fc1 + bkons1[_N] * (1 + ln(t-4)) if t>=5 & t ~= .
  * Between effects
  gen `piece'bc = bkons_be[_N] if t ~= .
}


* Graph 1 - Effect Changover Working Class - Self employed
* --------------------------------------------------------

* Delete some ylabels
foreach var of varlist arbselfc* arbselbc* selarbfc* selarbbc* {
  lab val `var' null
}
lab def null 0 " "


capture program drop mygraph
program define mygraph
  gph open, saving(mod3a, replace)
    local opt `"border c(JJJ[.]) pen(332) s(ioi) yscale(-2,2) gap(5)"'
    local opt `"`opt' key1(" ") l1t(" ") xlab(5) xtick(1(2)10) sort yline(0)"'
    graph arbselfl* arbselbl t, `opt' bbox(0,0,12000,17500,900,450,0)  /*
    */ ylab(-2(1)2)
    graph selarbfl* selarbbl t, `opt' bbox(11000,0,23000,17500,900,450,0)  /*
    */ ylab(-2(1)2)
    graph arbselfc* arbselbc t, `opt' bbox(0,14500,12000,32000,900,450,0) /*
    */ ylab(0) ytick(-2(1)2)
    graph selarbfc* selarbbc t, `opt' bbox(11000,14500,23000,32000,900,450,0)/*
    */ ylab(0) ytick(-2(1)2)
    gph pen 1
    gph font 700 350
    gph text 500 17500 0 0 Worker to Self Employed
    gph text 11500 17500 0 0 Self Employed to Worker
    gph text 22500 8750 0 0 Lefties Model
    gph text 22500 25250 0 0 Conservatives Model
    gph font 1000 500
    gph text 6000 1000 1 0 Fixed-Effects Coefficient
    gph text 16500 1000 1 0 Fixed-Effects Coefficient
  gph close
end
mygraph 


* Graph 2 - Effect of New Interaction Partners
* --------------------------------------------

* Delete some ylabels
foreach var of varlist parspdfc* parcdufc*  {
  lab val `var' null
}

capture program drop mygraph
program define mygraph
  gph open, saving(mod3b, replace)
    local opt `"border c(JJ) pen(33) s(io) yscale(-2,2) gap(5)"'
    local opt `"`opt' key1(" ") l1t(" ") xlab(5) xtick(1(2)10) sort yline(0)"'
    graph parspdfl* t, `opt' bbox(0,0,12000,17500,900,450,0)  /*
    */ ylab(-2(1)2)
    graph parcdufl* t, `opt' bbox(11000,0,23000,17500,900,450,0)  /*
    */ ylab(-2(1)2)
    graph parspdfc* t, `opt' bbox(0,14500,12000,32000,900,450,0) /*
    */ ylab(0) ytick(-2(1)2)
    graph parcdufc* t, `opt' bbox(11000,14500,23000,32000,900,450,0)/*
    */ ylab(0) ytick(-2(1)2)
    gph pen 1
    gph font 700 350
    gph text 500 17500 0 0 New Left Partner
    gph text 11500 17500 0 0 New Conservative Partner
    gph text 22500 8750 0 0 Lefties Model
    gph text 22500 25250 0 0 Conservatives Model
    gph font 1000 500
    gph text 6000 1000 1 0 Fixed-Effects Coefficient
    gph text 16500 1000 1 0 Fixed-Effects Coefficient
  gph close
end
mygraph 


exit