* Parteiidentifikation und Sozialstrukturelle Variablen  
* 16 Wellen, Unbalanced Panel-Design, mit Marker fuer Balanced
* Langes Format, xtdata, weights


* ATTENTION: This Do-File automatically installs 
* Stata-Ados from the Internet. Comment the section
* "Cool-Ados" if you want to install them by hand!


clear
set memory 120m
version 7.0
set more off

*+--------------------------------+
*| INSTALLATION VON ZUSATZMODULEN |
*+--------------------------------+

* COOL-ADOS: Diese Ados werden im Folgenden automatisch über das 
* Internet geladen und installiert.
* Das setzt natürlich voraus, dass ihr Rechner eine feste Verbindung 
* zum Internet hat. Sollte dies nicht der Fall sein müssen Sie die 
* entsprechenden Ados von Hand installieren. Hinweise hierzu in 
* Kohler/Kreuter (2001)


capture which archinst 
if _rc ~= 0	{
	net stb-54
	net install ip29.1
}

capture which mkdat
if _rc ~= 0 {
	net from http://www.sowi.uni-mannheim.de/lehrstuehle/lesas/ado
	net install mkdat
}

capture which soepren
if _rc ~= 0 {
	net from http://www.sowi.uni-mannheim.de/lehrstuehle/lesas/ado
	net install soepren
}


capture which mmerge
if _rc ~= 0 {
	archinst mmerge
}


* +--------+
* |Retrival|
* +--------+
* (unbalanced Panel-Design)

* Parteineigung, Interviewernummern, fruehere Bst
* -----------------------------------------------

mkdat  /*
*/ ap08 bp16 cp16 dp12 ep12 fp10 gp12 hp15 ip15 jp15 kp25 lp21  /*
*/ mp15 np11 op09 pp10  /*
*/ ap5601 bp7901 cp7901 dp8801 ep7701 fp9301 gp8501 hp9001 ip9001 jp9001  /*
*/ kp9201 lp9801 mp8401 np9401 op9701 pp111  /*
*/ ap5602 bp7902 cp7902 dp8802 ep7702 fp9302 gp8502 hp9002 ip9002 jp9002  /*
*/ kp9202 lp9802 mp8402 np9402 op9702 pp11201  /*
*/ _X1 bpintnr cpintnr dpintnr epintnr fpintnr gpintnr hpintnr ipintnr  /*
*/ jpintnr kpintnr lpintnr mpintnr npintnr opintnr ppintnr   /*
*/ ap1601 bp24b01 cp24b01 dp22b01 ep22b01 fp20b01 gp23b01 hp25b01  /*
*/ ip25b01 jp25b01 _x1 _x11 _x21 _x21a _n1 _n6 /*
*/ ap1602 bp24b02 cp24b02 dp22b02 ep22b02 fp20b02 gp23b02 hp25b02  /*
*/ ip25b02 jp25b02 _x2 _x12 _x22 _x22a _n2 _n7  /*
*/ ap1603 bp24b03 cp24b03 dp22b03 ep22b03 fp20b03 gp23b03 hp25b03  /*
*/ ip25b03 jp25b03 _x3 _x13 _x23 _x23a _n3 _n8 /*
*/ ap1604 bp24b04 cp24b04 dp22b04 ep22b04 fp20b04 gp23b04 hp25b04  /*
*/ ip25b04 jp25b04 _x4 _x14 _x24 _x24a _n4 _n9  /*
*/ ap1605 bp24b05 cp24b05 dp22b05 ep22b05 fp20b05 gp23b05 hp25b05  /*
*/ ip25b05 jp25b05 _x5 _x15 _x25 _x25a _n5 _n10        /*
*/ using $soepdir, netto(-3,-2,-1,0,1,2,3,4,5) files(p)  /*
*/ waves(a b c d e f g h i j k l m n o p) keep(sex gebjahr psample)

holrein aintnr using $soepdir, files(pbrutto) waves(a)

* Bildung, EGP
* ------------

holrein /*
*/ apsbil bpsbil cpsbil dpsbil epsbil fpsbil gpsbil hpsbil /*
*/ ipsbil jpsbil kpsbil lpsbil mpsbil npsbil opsbil ppsbil  /*
*/ goldth84 goldth85 goldth86 goldth87 goldth88 goldth89 goldth90  /*
*/ goldth91 goldth92 goldth93 goldth94 goldth95 goldth96 goldth97  /*
*/ goldth98 goldth99 /*
*/ isco84 isco85 isco86 isco87 isco88 isco89 isco90 isco91 isco92 /*
*/ isco93 isco94 isco95 isco96 isco97 isco98 isco99  /*
*/ using $soepdir, files(pgen) waves(a b c d e f g h i j k l m n o p) 

* Einkommenskalendarien
* ---------------------

holrein  /*
*/ ap2a02 bp2a02 cp2a02 dp2a02 ep2a02 fp2a02 gp2a02 /* Monate Lohn/Gehalt 
*/ hp2a02 ip2a02 jp2a02 kp2a02 lp2a02 mp2a02 np2a02 op2a02 pp2a02 /*
*/ ap2b02 bp2b02 cp2b02 dp2b02 ep2b02 fp2b02 gp2b02 /* Monate Einkommen 
*/ hp2b02 ip2b02 jp2b02 kp2b02 lp2b02 mp2b02 np2b02 op2b02 pp2b02 /*
*/ ap2c02 bp2c02 cp2c02 dp2c02 ep2c02 fp2c02 gp2c02 /* Monate Nebenerwerb 
*/ hp2c02 ip2c02 jp2c02 kp2c02 lp2c02 mp2c02 np2c02 op2c02 pp2c02 /*
*/ ap2d02 bp2d02 cp2d02 dp2d02 ep2d02 fp2d02 gp2d02 /* Monate Rente/Pension 
*/ hp2d02 ip2d02 jp2d02 kp2d02 lp2d02 mp2d02 np2d02 op2d02 pp2d02 /*
*/ ap2f02 bp2f02 cp2f02 dp2f02 ep2f02 fp2f02 gp2f02 /* Monate Arbeitslosengeld 
*/ hp2f02 ip2f02 jp2f02 kp2f02 lp2f02 mp2f02 np2f02 op2f02 pp2f02 /*
*/ ap2g02 bp2g02 cp2g02 dp2g02 ep2g02 fp2g02 gp2g02 /* Monate Arbeitsl.-hilfe
*/ hp2g02 ip2g02 jp2g02 kp2g02 lp2g02 mp2g02 np2g02 op2g02 pp2g02 /*
*/ ap2h02 bp2h02 cp2h02 dp2h02 ep2h02 fp2h02 gp2h02 /* Mon. Unterh. Arbeitsamt 
*/ hp2h02 ip2h02 jp2h02 kp2h02 lp2h02 mp2h02 np2h02 op2h02 pp2h02 /*
*/ ap2k02 bp2k02 cp2k02 dp2k02 ep2k02 fp2k02 gp2k02 /* Mon. Baf"og, Stipendien 
*/ hp2k02 ip2k02 jp2k02 kp2k02 lp2k02 mp2k02 np2k02 op2k02 pp2k02 /*
*/ ap2a03 bp2a03 cp2a03 dp2a03 ep2a03 fp2a03 gp2a03 /* Lohn/Gehalt           
*/ hp2a03 ip2a03 jp2a03 kp2a03 lp2a03 mp2a03 np2a03 op2a03 pp2a03 /*		 
*/ ap2b03 bp2b03 cp2b03 dp2b03 ep2b03 fp2b03 gp2b03 /* Einkommen             
*/ hp2b03 ip2b03 jp2b03 kp2b03 lp2b03 mp2b03 np2b03 op2b03 pp2b03 /*		 
*/ ap2c03 bp2c03 cp2c03 dp2c03 ep2c03 fp2c03 gp2c03 /* Nebenerwerb           
*/ hp2c03 ip2c03 jp2c03 kp2c03 lp2c03 mp2c03 np2c03 op2c03 pp2c03 /*		 
*/ ap2d03 bp2d03 cp2d03 dp2d03 ep2d03 fp2d03 gp2d03 /* Rente/Pension         
*/ hp2d03 ip2d03 jp2d03 kp2d03 lp2d03 mp2d03 np2d03 op2d03 pp2d03 /*		 
*/ ap2f03 bp2f03 cp2f03 dp2f03 ep2f03 fp2f03 gp2f03 /* Arbeitslosengeld      
*/ hp2f03 ip2f03 jp2f03 kp2f03 lp2f03 mp2f03 np2f03 op2f03 pp2f03 /*		 
*/ ap2g03 bp2g03 cp2g03 dp2g03 ep2g03 fp2g03 gp2g03 /* Arbeitslosenhilfe     
*/ hp2g03 ip2g03 jp2g03 kp2g03 lp2g03 mp2g03 np2g03 op2g03 pp2g03 /*		 
*/ ap2h03 bp2h03 cp2h03 dp2h03 ep2h03 fp2h03 gp2h03 /* Unterh. vom Arbeitsam 
*/ hp2h03 ip2h03 jp2h03 kp2h03 lp2h03 mp2h03 np2h03 op2h03 pp2h03 /*		 
*/ ap2k03 bp2k03 cp2k03 dp2k03 ep2k03 fp2k03 gp2k03 /* Mon. Baf"og, Stipendie
*/ hp2k03 ip2k03 jp2k03 kp2k03 lp2k03 mp2k03 np2k03 op2k03 pp2k03 /*
*/ using $soepdir,  /*
*/ files(pkal) waves(a b c d e f g h i j k l m n o p) 

* Stellung im Haushalt
* --------------------

holrein /*
*/ astell bstell cstell dstell estell fstell gstell hstell istell  /*
*/ jstell kstell lstell mstell nstell ostell pstell  /*
*/ using $soepdir, files(pbrutto) waves(a b c d e f g h i j k l m n o p) 

* Nie erwerbstaetig
holrein ap09 aisco using $soepdir, files(p) waves(a) 

* +---------------+
* | Rekodierungen |
* +---------------+

* Haushaltsnummer
* ---------------

soepren ?hhnr, new(hnr) w(84/99)

* Befragenstatus
* --------------

soepren ?netto, new(netto) w(84/99)

* Stellung im Haushalt
* --------------------

soepren ?stell, new(hst) w(84/99)

* Interviewernummer
* -----------------

soepren *intnr, new(intnr) w(84/99)

* Parteineigung
* -------------

lab def pid 1 "Keine" 2 "SPD" 3 "CDU/CSU" 4 "FDP" 5 "B90/Gr" /*
*/ 6 "Andere P"

* Wellen a - g
local i 84
foreach piece in ap56 bp79 cp79 dp88 ep77 fp93 gp85 {
            gen pid`i' = 1 if `piece'01 == 2
            replace pid`i' = 2 if `piece'02==1
            replace pid`i' = 3 if `piece'02>=2 & `piece'02<=4
            replace pid`i' = 4 if `piece'02==5
            replace pid`i' = 5 if `piece'02==6
            replace pid`i' = 6 if `piece'02==7 | `piece'02==8
            lab var pid`i' "Parteiidentifikation"
            lab val pid`i' pid
            local i = `i' + 1
}
    

* Welle h
gen pid91 = 1 if hp9001 == 2
replace pid91 = 2 if hp9002==1
replace pid91 = 3 if hp9002==2
replace pid91 = 4 if hp9002==3
replace pid91 = 5 if hp9002==4 | hp9002==5
replace pid91 = 6 if hp9002>=6 & hp9002<=8
lab var pid91 "Parteiidentifikation"
lab val pid91 pid

* Wellen i,j,
local i 92
foreach piece in ip90 jp90 {
            gen pid`i' = 1 if `piece'01 == 2
            replace pid`i' = 2 if `piece'02==1
            replace pid`i' = 3 if `piece'02>=2 & `piece'02<=3
            replace pid`i' = 4 if `piece'02==4
            replace pid`i' = 5 if `piece'02==5 | `piece'02==6
            replace pid`i' = 6 if `piece'02==7 | `piece'02==8 | `piece'02==9
            lab var pid`i' "Parteiidentifikation"
            lab val pid`i' pid
            local i = `i' + 1
}

* Wellen k, l, m, n
local i 94
foreach piece in kp92 lp98 mp84 np94 {
            gen pid`i' = 1 if `piece'01 == 2
            replace pid`i' = 2 if `piece'02==1
            replace pid`i' = 3 if `piece'02>=2 & `piece'02<=3
            replace pid`i' = 4 if `piece'02==4
            replace pid`i' = 5 if `piece'02==5
            replace pid`i' = 6 if `piece'02>=6 & `piece'02<=8
            lab var pid`i' "Parteiidentifikation"
            lab val pid`i' pid
            local i = `i' + 1
}

* Welle o
gen pid98 = 1 if op9701 == 2
replace pid98 = 2 if op9702==1
replace pid98 = 3 if op9702==2 | op9702==3 | op9702==13
replace pid98 = 4 if op9702==4
replace pid98 = 5 if op9702==5
replace pid98 = 6 if op9702>=6 & op9702<=22
lab var pid98 "Parteiidentifikation"
lab val pid98 pid
                                  
* Welle p
gen pid99 = 1 if pp111 == 2
replace pid99 = 2 if pp11201==1
replace pid99 = 3 if pp11201==2 | pp11201==3 | pp11201==13
replace pid99 = 4 if pp11201==4
replace pid99 = 5 if pp11201==5
replace pid99 = 6 if pp11201>=6 & pp11201<=23
lab var pid99 "Parteiidentifikation"
lab val pid99 pid


* Erwerbsstatus
* -------------

soepren ap08 bp16 cp16 dp12 ep12 fp10 gp12 hp15 ip15 jp15 kp25 lp21  /*
*/ mp15 np11 op09 pp10, new(est) w(84/99)

* Erwerbstatus seit 91
forvalues i=91/95 {
	recode est`i' 1 2=1 3 4=2 5=3 6=4 8=6 7 9=7
    note est`i': recodiert
}

* Erwerbstatus 96 u. 97 
forvalues i=96/97 {
	recode est`i' 5=7
    note est`i': recodiert
}

* Erwerbstatus 98 u. 99
forvalues i=98/99 {
	recode est`i' 5=7 8=7
    note est`i': recodiert
}

for varlist est*: lab val X est
lab def est 1 "Vollzeit" 2 "Teilzeit" 3 "Umschul." 4 "Unregelm" /*
         */  5 "arb.los" 6 "Wehrd." 7 "not erw."

* Nie Erwerbstaetig
* -----------------

gen byte nie84 = ap09==2
lab var nie84 "bis 84 nie erwerbstaetig"
lab val nie84 yesno
note nie84: SOEP-Name ap09

forvalues i=85/99 {
	local j = `i'-1
	gen byte nie`i' = 0
	replace nie`i' = 1 /*
	*/ if (est`i' == 6 | est`i' == 7) & nie`j' == 1
	lab var nie`i' "bis `i' nie erwerbstaetig"
	lab val nie`i' yesno
	note nie`i': gneriert aus ap09 und Fortschreibung Erwerbsstatus
}

lab def yesno 0 "nein" 1 "ja"


* Berufsbezogenens persoenliches Einkommen (-> Note 1)
* ---------------------------------------

local i 84
foreach wave in a b c d e f g h i j k l m n o p {
	gen ein`i' = 0 if netto`i' == 1 | netto`i' == 4
	quietly {

		* Pro Jahr
		foreach typ in a b c d f g h k {
			local month `wave'p2`typ'02
			local wage `wave'p2`typ'03
	    	replace `month' = . if `month'  <= 0
			replace `wage' = . if `wage' <= 0
	    	replace ein`i' = ein`i' + (`month' *  `wage') if `wage' ~= . /*
			*/ & `month' ~= .
		}

		* Pro Monat
		replace ein`i' = ein`i'/12

	    * Einkommen von 0: Missing
   		 replace ein`i' = . if ein`i' ==  0
	}

    lab var ein`i' "Berufsbez. pers. Bruttoeinkommen `i'"
    local i=`i'+1
}

drop ?p2?0?


* Bildung
* -------

soepren ?psbil, new(bil) wave(84/99)
foreach var of varlist bil* {
	replace `var' = . if `var' < 0
}


* Fruehere berufliche Stellung 
* ----------------------------

* bis Welle 93
local i 84
foreach piece in ap16 bp24b cp24b dp22b ep22b fp20b gp23b hp25b ip25b jp25b {
	quietly {
		 gen bst`i' = .

	     * Beamten
    	 replace bst`i'=40 if `piece'05==1 /* einfach */
	     replace bst`i'=41 if `piece'05==2 /* mittel */
    	 replace bst`i'=42 if `piece'05==3 /* gehoben */
	     replace bst`i'=43 if `piece'05==4 /* hoeher */

    	 * Angestellte
	     if `i'< 91 {
	             replace bst`i'=50 if `piece'04==1 /* Ind. Werkmeister */
	             replace bst`i'=51 if `piece'04==2 /* einfach */
	             replace bst`i'=52 if `piece'04==3 /* qualif */
	             replace bst`i'=53 if `piece'04==4 /* hochqualif */
	             replace bst`i'=54 if `piece'04==5 /* fuehrung */
	     }
	     else if `i' >= 91 {
	             replace bst`i'=50 if `piece'04==1 /* Ind. Werkmeister */
    	         replace bst`i'=51 if `piece'04==2 | `piece'04==3 /* einf. */
        	     replace bst`i'=52 if `piece'04==4 /* qualif */
            	 replace bst`i'=53 if `piece'04==5 /* hochqualif */
	             replace bst`i'=54 if `piece'04==6 /* fuehrung */
    	 }

	     * Arbeiter
	     replace bst`i'=60 if `piece'01==1 /* ungelernt */
	     replace bst`i'=61 if `piece'01==2 /* angelernt */
	     replace bst`i'=62 if `piece'01==3 /* Facharbeiter */
	     replace bst`i'=63 if `piece'01==4 /* Vorarbeiter */
	     replace bst`i'=64 if `piece'01==5 /* Meister */

	     * Auszubildende
	     replace bst`i'=70 if `piece'03==1 /* Azubi */
	     replace bst`i'=70 if `piece'03==2 /* Praktikant */

	     * Selbstaendige
	     replace bst`i'= 10 if `piece'02==1 /* Landwirte */
	     replace bst`i'= 15 if `piece'02==2 /* freie Berufe */
	     replace bst`i'= 21 if `piece'02==3 /* Selb < 9 */
	     replace bst`i'= 23 if `piece'02==4 /* Selb >= 10 */
	     replace bst`i'= 30 if `piece'02==5 /* Mithelfend */
	     note bst`i': SOEP-Name `piece'01-`piece'05
	     drop `piece'01 `piece'02 `piece'03 `piece'04 `piece'05
		local i = `i'+1
	}
}

* Frueherer Beruf
* ----------------

soepren aisco, new(isc) wave(84)
replace isc84 = . if est84 >= 1 & est84 <= 4
replace isc84 = . if isc84 < 0


* +-------+
* |Reshape|
* +-------+

keep hhnr persnr sex gebjahr psample netto* hst* hnr* pid* bst* isc* bil* /*
*/ goldth*  ein* est* intnr*
reshape long hnr netto intnr hst pid bst isc isco bil goldth ein est,  /*
*/ i(persnr) j(welle)


* +------------------------------+
* |Fortschreibung frueherer Beruf|
* +------------------------------+

sort persnr welle
by persnr (welle): replace bst=bst[_n-1] if est >= 5 & est<= 7  & _n~=1
by persnr (welle): replace isc=isc[_n-1] if est >= 5 & est<= 7  & _n~=1


* +-----------+
* |EGP-Klassen|
* +-----------+

* Zuweisung durch EGP-Master-File
* -------------------------------

* cregp gelaufen?, wenn nein dann jetzt!

capture d using egp  
if _rc~= 0 {
	preserve
	do cregp
	restore
}

* Merge zu jeder ISC-Bst Kombination die Klasse aus dem 
* EGP-Master zu

mmerge bst isc using egp, type(n:1) missing(value)  /*
*/ unmatched(master) 

* Verwendung der SOEP-Origanalvariablen wo moeglich
* -------------------------------------------------

replace egp = goldth if goldth >= 0 & goldth ~= .


* Einordnung ueber den Hauptverdiener/Haushaltsvorsitzender
* ---------------------------------------------------------

gen hstmir = 99-hst
sort welle hnr ein hstmir persnr
by welle hnr: gen egph = egp[_N] if ein[_N] ~= .

sort welle hnr hst persnr
by welle hnr: replace egph = egp[1]  /*
*/ if egph == . & hst[1] >= 0 & hst[1] <= 2

* Beruf = aktueller Beruf oder frueherer Beruf
replace isco = isc if isco <= 0 

* Hauptverdiener-Beruf
sort welle hnr ein hstmir persnr
by welle hnr: gen isch = isco[_N] if ein[_N] ~= .

sort welle hnr welle hst persnr
by welle hnr: replace isch = isco[1]  /*
*/ if isch == . & hst[1] >= 0 & hst[1] <= 2


* Mueller - EGP
* -------------
* (Quelle: http://www.uni-koeln.de/kzfss/ks-mueta.htm)

* Administrative Dienstklasse (ISCO 1 und 2; 121-129; 201-999)
gen megph = 1 if (egph == 1 | egph == 2) &  /*
*/ ((isch==1 | isch==2) | (isch>=121 & isch<=129) | (isch>=201 & isch<=999))

* Experten (ISCO 11-54; 81-110)
replace  megph = 2 if (egph == 1 | egph == 2) &   /*
*/ ((isch>=11 & isch<=54) | (isch>=81 & isch<=110))

* Soziale Dienstleistungen  (ISCO 61-79; 131-199) 
replace  megph = 3 if (egph == 1 | egph == 2) &   /*
*/ ((isch>=61 & isch<=79) | (isch>=131 & isch<=199))

* Rest
replace megph = egph + 1 if egph > 2 & egph ~= .  

* Beschriftung
lab var megph "Mueller-EGP (Hauptverdiener)"
lab val megph megp 
lab def megp 1 "Admin. D." 2 "Experten" 3 "Soz. D."  4 "Non-man"  /*
*/  5 "gr.Selb." 6 "kl.Selb."  7 "selb.Lw." 8 "Vorarb."  /*
*/  9 "Facharb." 10 "Un/Angel" 11 "Landarb"  12 "Heimber"
drop egp egph



* +-----------------+
* |Zusammenfassungen|
* +-----------------+

* EGP
* ---

gen egp = 1 if megp >= 5 & megp <= 7 /* Selbständige */
replace egp = 2 if megp == 1 /* Administrative Dienste */
replace egp = 3 if megp == 2 /* Experten */
replace egp = 4 if megp == 3 /* Soziale Dienste */
replace egp = 5 if megp == 4 | megp == 8 | megp == 12 /* Mischtypen */
replace egp = 6 if megp >= 9 & megp <= 11 /* Arbeiter */
lab var egp "Mueller - EGP, 6er Teilung"
lab val egp megp6
lab def megp6 1 "Selb." 2 "Ad. D." 3 "Experten" 4 "Soz. D." 5 "Mischt."  /*
*/ 6 "Arb."
drop megph

* PID
* ---

gen pi = 1 if pid == 2 /* SPD */ 
replace pi = 2 if pid == 3 | pid == 4  /* CDU, FDP */
replace pi = 3 if pid == 5 /* B90 */

* Bildung
* -------

gen hbil = bil == 3 | bil == 4
drop bil

* Alter und Kohorte
* -----------------

gen age = (1900 + welle) - gebjahr if gebjahr > 0
gen olds = gebjahr<1940 if gebjahr > 0
drop gebjahr

* Geschlecht
* ----------

gen men = sex==1 if sex > 0 
drop sex

* +--------------------+
* |Stimmung im Haushalt|
* +--------------------+

* 1. Stufe: Mehrpersonenhaushalte
* -------------------------------
* (Die Imputation fuer Einpersonenhaushalte wird bei den Analysen vorgenommen)


* Anzahl weiterer Personen mit gueltiger PID im HH des Befragten
sort welle hnr 
by welle hnr: gen valid = sum(pid~=.) 
by welle hnr: replace valid = valid[_N]
replace valid = valid-1 if pid ~= .

* Anzahl Anhaenger bestimmter Parteien im HH
by welle hnr: gen kons = sum(pid==3 | pid==4)
by welle hnr: gen spd = sum(pid==2)
by welle hnr: gen b90 = sum(pid==5)
by welle hnr: replace kons = kons[_N]  /* Anzahl CDU - Anhänger */
by welle hnr: replace spd = spd[_N]    /* Anzahl SPD - Anhänger */
by welle hnr: replace b90 = b90[_N]    /* Anzahl B90 - Anhänger */

* Anzahl Anhaenger ohne den Befragten
replace kons = kons -1 if pid == 3 | pid == 4 
replace spd = spd -1  if pid == 2 
replace b90 = b90 -1  if pid == 5 

* Anteil Anhaenger bestimmter Parteien unter den anderen Personen im HH
replace kons = kons/valid
replace spd = spd/valid
replace b90 = b90/valid

* Don't use 1 Pers. HH 
replace kons = . if valid <= 0
replace spd = . if valid <= 0
replace b90 = . if valid <= 0
drop valid


* +-------+
* |XT-Data|
* +-------+

iis persnr
tis welle

* +-----------------------+
* |Merge Weights & Rgroups|
* +-----------------------+

capture d using weights
if _rc~= 0 {
	preserve
	do crweigts
	restore
}

mmerge persnr using weights, type(n:1) unmatched(master)
drop _merge

* +---------------+
* |Balanced Sample|
* +---------------+

sort persnr welle
by persnr: gen mark=sum(netto==1)
by persnr: replace mark=mark[_N]==16
label variable mark "Balanced Sample"
lab val mark yesno


* +----+
* |Save| 
* +----+

keep persnr welle hnr psample mark intnr hbil pid pi egp prgroup bw uw men  /*
*/ kons spd b90 olds age
compress
save traeg, replace

exit


Note 1
------

Berufsbezogenes pers"onliches Bruttoeinkommen

Das berufsbezogene pers"onliche Bruttoeinkommen wird durch die Summe aller
Einkommensarten, die aus der aktuellen oder ehemaligen beruflichen Postion
resultieren, gem"a"s folgender Formel ermittelt:

\begin{equation}
\mbox{berufsbez. pers. Bruttoeink}
= \frac{1}{12} \sum_{i=1}^I \left(f_i * x_i\right)
\end{equation}

Dabei ist $ i $ eine von $ I $ Einkommensarten, die aus der berufliche
Position resultieren, $ f $ sind die Anzahl der Monate, in der eine
Einkommensart bezogen wurde und $ x $ der vom Befragen gesch"atzte
durchschnittliche Betrag dieser Einkommensart f"ur den angegebenen Zeitraum.
Verwendet werden Einkommen des abgelaufenen Kalenderjahrs.

Folgende Einkommensarten wurden als "`aus der beruflichen Position
resultierent"' angesehen:

\begin{enumerate}
\item Lohn oder Gehalt als Arbeitnehmer (einschl. Ausbildungsverg"utung und
  Vorruhestandsbez"uge)
\item Einkommen aus selbst"andiger oder freiberuflicher T"atigkeit
\item Einkommen aus Nebenerwerbst"atigkeit, Nebenverdienste
\item Altersrente oder -pension, Invalidenrente und Betriebsrente aufgrund
  eigener Erwerbst"atigkeit
\item Arbeitslosengeld
\item Arbeitslosenhilfe
\item Unterhaltsgeld vom Arbeitsamt bei Fortbildung oder Umschulung
\item Baf"og, Stipendium oder Berufsausbildungsbeihilfe
\end{enumerate}

Als nicht aus der beruflichen Position resultierend galten Witwen- und
Waisenrenten, bzw.\ -pensionen sowie Zahlungen von Personen, die nicht im
Haushalt leben.

In einigen F"allen findet sich der Missing--Code -2 (trifft nicht zu) bei
der Angabe des Betrags einer Einkommensart, obwohl bei der Anzahl der Monate
eine g"ultige Angabe eingetragen wurde. Hier wurde stets der Anzahl der Monate
Vorrang einger"aumt, und der Missing--Code bei der Angabe des Betrags auf
-1 gesetzt.


Note 2
------


Angabe zur Konfession enthält Mehfachnennungen. Alle Beobachtungen mit
Mehrfachnennungen wurden auf die "Kategorie" Sonstiges
gesetzt. Sonstiges ist damit "Andere christliche, Nichtchristliche,
Mehrfachnennungen und keine Angabe".